; Timer Manager v1.03
; by ch1zra
; ch1zra@gmail.com
; http://ch1zra.com/mirc/
; #Scripters @ irc.krstarica.com
; Copyright © Up The Irons ! inc. 
; ---]> Aliases

; this one improves the mIRC's /timers command. 
; it gives a nice, in dialog view of all active timers, 
; with their interval, number of repeatings, and option to
; stop any of them.


alias Timers {
  if ($dialog(TimerManager)) {
    dialog -vea TimerManager TimerManager
  }
  else { dialog -mdo TimerManager TimerManager }
}

alias timerlist {
  did -r $dname 5,7
  did -r timermanager 3
  var %i 1
  while (%i <= $timer(0)) {
    did -a timermanager 3 $timer(%i)
    inc %i
  }
}

alias -l timer.about {
  dialog -i TimerManager TimerManager 
  if ($input(TimerManager v1.0b $crlf $crlf by ch1zra $crlf $crlf http://www.uptheirons.co.sr/ $crlf ch1zra@gmail.com $crlf $& 
    #Scripters @ irc.krstarica.com $crlf #Hawkee.com @ irc.undernet.org $crlf $crlf Copyright © Up The Irons ! inc. Scripting $&
    Team,oi,About Timer Manager) == $true) {
    dialog -e TimerManager TimerManager 
  }
}

; ---]> Dialog

dialog TimerManager {
  title "Timer Manager v1.0b by ch1zra"
  size -1 -1 135 110
  option dbu
  box "/Timers", 1, 5 5 125 85
  text "Timer Name :", 2, 10 15 65 10
  list 3, 10 25 45 60, sort size vsbar
  text "Command : ", 4, 59 25 65 8
  edit "", 5, 60 35 65 10, read autohs
  text "Interval / Repetitions :", 6, 60 50 65 8
  edit "", 7, 60 60 65 10, read autohs
  button "Stop", 8, 60 75 30 10, flat
  button "Refresh", 9, 95 75 30 10, flat
  button "About", 10, 5 95 35 10, flat
  button "Help", 11, 50 95 35 10, flat
  button "Close", 12, 95 95 35 10, flat ok
}

; ---]> On Init and Close

on *:dialog:timermanager:init:*: {
  timerlist
}

; ---]> Sclicks

on *:dialog:TimerManager:sclick:*: { 
  if ($did == 3) { 
    did -r $dname 5,7
    if ($did(3).seltext != $null) {
      did -a $dname 5 $timer($did(3).seltext).com
      var %rps $timer($did(3).seltext).reps
      if (%rps == 0) {
        did -a $dname 7 Forever / $duration($timer($did(3).seltext).delay)
      }
      else { did -a $dname 7 $timer($did(3).seltext).reps time(s) / $duration($timer($did(3).seltext).delay) } 
    }
  }
  if ($did == 8) { 
    if ($did(3).seltext != $null) {
      .timer $+ $did(3).seltext off
      echo -a  $+ $color(info) $+ *** Timer  $+ $color(highligt) $+  $+ $did(3).seltext $+   $+ $color(info) $+ Turned oFF
    }
    else {
      echo -a  $+ $color(info) $+ *** Timer Manager : You Must Select a Timer from List !
    }
    timerlist
  }
  if ($did == 9) {
    timerlist
  }
  if ($did == 10) {
    timer.about
  }
  if ($did == 11) {
    dialog -i TimerManager TimerManager
    help /timer
  }
}